-- MATH 531: Oct 25. -- Resultants via M2.
restart

-- Res_{2,2,2} -- Ternary quadrics
C = QQ[c_{0,1}..c_{2,6}]
describe C
R = C[x,y,z];
F = apply(3, i -> c_{i,1}*x^2 + c_{i,2}*y^2 + c_{i,3}*z^2
                + c_{i,4}*x*y + c_{i,5}*x*z + c_{i,6}*y*z)
JM = jacobian ideal F 
J = det JM
degree J
-- G is the list of the derivatives of J 
G = first entries transpose jacobian ideal J; 
coefficients G_1
-- M is the matrix of coefficients of the 6 quadrics in F and G
M = matrix(apply(F|G,r->first entries (coefficients r)#1))
M = sub(M,C); -- convert to the ring C
time Res222 = (-1/512)*det(M,Strategy=>Cofactor);
size Res222
-- create the map that substitutes coefficients of x^2,y^2,z^2 
-- for the indeterminate coefficients
M = map(QQ,C,{1,0,0,0,0,0, -- x^2
	       0,1,0,0,0,0, -- y^2 
	       0,0,1,0,0,0 -- z^2
	       }) 
-- check that Res(x^2,y^2,z^2)=1
M Res222

-- Res_{1,1,2}
C = QQ[a_1..a_3, b_1..b_3, c_1..c_6];
R = C[x,y,z];
F = {a_1*x+a_2*y+a_3*z,
     b_1*x+b_2*y+b_3*z,
     c_1*x^2 + c_2*y^2 + c_3*z^2 + c_4*x*y + c_5*x*z + c_6*y*z}
G = {x*F_0,y*F_0,z*F_0,x*F_1,y*F_1,F_2}
coefficients transpose matrix{G}
D = det sub(oo#1,C)
fD = factor D
Res112 = fD#0#0 -- the first factor of D
M = map(QQ,C,{1,0,0, -- x
	       0,1,0, -- y 
	       0,0,1,0,0,0 -- z^2
	       }) 
M Res112 -- Res(x,y,z^2)=1